home *** CD-ROM | disk | FTP | other *** search
/ LOGIC Apps / Logic-APPLE_II_APPS.iso / mac / LOGIC Apple II 5.25" Library - ProDOS / PRO050.dsk / DATA.SAVER.bas < prev    next >
BASIC Source File  |  2012-02-16  |  2KB  |  42 lines
  1. 10  REM  ***  DATA.SAVER  *** (ProDos Inside & Out p.77)
  2. 100 D$ =  CHR$(4)
  3. 110 P1$ = "/RAM/": REM  prefix of volume that files are to be copied FROM
  4. 120  REM   P2$= prefix of volume that files are to be copied TO (DEFINED IN CW)
  5. 130 F$ = "ONGOING.DATA":T$ = "TXT": GOSUB 400: REM  names and types of files to copy
  6. 140 F$ = "MAIN.DATA":T$ = "TXT": GOSUB 400
  7. 150 F$ = "CAT.DATA":T$ = "TXT": GOSUB 400
  8. 160 F$ = "RECUR.TRANS":T$ = "TXT": GOSUB 400
  9. 170 F$ = "RECON.BAL.DATA":T$ = "TXT": GOSUB 400
  10. 180 F$ = "RT.CODE.DATA":T$ = "TXT": GOSUB 400
  11. 290  PRINT D$;"CHAIN /RAM/CW,@3100": REM  next program to run
  12. 300  END 
  13. 400 B = 0:A = 0:E = 0:L = 0: REM  Important--messing with this line can be fatal
  14. 405 X1 = 0:X2 = 0:CMD = 0
  15. 410  PRINT D$;"FRE"
  16. 420 A =  PEEK(109) + PEEK(110) *256
  17. 425 E =  PEEK(111) + PEEK(112) *256
  18. 430  ONERR  GOTO 500
  19. 440  PRINT D$;"CREATE";P2$;F$;",T";T$
  20. 450  PRINT D$;"BLOAD";P1$;F$;",T";T$;",A";A;",E";E -1;",B";B
  21. 455 CMD = 196: GOSUB 600:X1 =  PEEK(48825):X2 =  PEEK(48826)
  22. 460 L =  PEEK(48859) + PEEK(48860) *256
  23. 470  PRINT D$;"BSAVE";P2$;F$;",T";T$;",A";A;",L";L;",B";B
  24. 475 CMD = 195: POKE 48820,7: POKE 48825,X1: POKE 48826,X2: GOSUB 600
  25. 480  IF L = (E -A)  THEN B = B +L: GOTO 450
  26. 490  POKE 216,0: RETURN 
  27. 500  IF  PEEK(222) = 19  THEN  PRINT D$;"DELETE";P2$;F$: RESUME 
  28. 510  IF  PEEK(222) = 5  THEN  CALL  -3288: GOTO 490
  29. 512  IF  PEEK(222) = 6  THEN  CALL  -3288: GOTO 550
  30. 514  IF  PEEK(222) = 8  THEN  CALL  -3288: GOTO 550
  31. 520  PRINT "ERROR #"; PEEK(222);" IN LINE "; PEEK(218) + PEEK(219) *256
  32. 530  END 
  33. 550  REM  DISK I/O ERROR
  34. 555  HOME : PRINT D$;"PR#3": PRINT 
  35. 560  HTAB 20: VTAB 3: PRINT "CANNOT FIND YOUR PATHWAY, PLEASE REENTER"
  36. 565  HTAB 27: PRINT "CHOOSE <ANYKEY> TO CONTINUE"
  37. 570  HTAB 40: VTAB 6:FS = 1: GET X$: POKE 216,0
  38. 575  PRINT D$;"CHAIN /RAM/CW,@55000"
  39. 600  REM  *** MLI caller for use with BASIC.SYSTEM ***
  40. 610  POKE 48728,169: POKE 48729,CMD: POKE 48730,32
  41. 620  POKE 48731,112: POKE 48732,190: POKE 48733,176
  42. 630  POKE 48734,170: POKE 48735,96: CALL 48728: RETURN